dokka/PKGBUILD

# -*- mode: Shell-script; eval: (setq indent-tabs-mode 't); eval: (setq tab-width 4) -*-
# Maintainer: Dominic Meiser [git at msrd0 dot de]

pkgname='dokka'
pkgver=1.9.20
pkgrel=1
pkgdesc='Documentation Engine for Kotlin'
url="https://kotlin.github.io/dokka/$pkgver/"
license=('Apache')
arch=('any')

depends=('freemarker' 'java-environment')
makedepends=('gradle' 'jdk11-openjdk' 'npm')

source=("https://github.com/Kotlin/dokka/archive/refs/tags/v$pkgver.tar.gz"
		'0001-enable-application-plugin.patch'
		'0002-embed-plugin-dependencies.patch'
		'0003-disable-gradle-enterprise.patch'
		'dokka')
sha256sums=('c1d2e9b0547c9a8023f0fb81e8d7ceabc25a11a1de20e387010217a79ade4ac2'
            '022deed27194a1cca2b981b1cd941828a4f1446c91af1f8339a4adfb983667b3'
            'e4a33df4d96234ef7be45811b6422c6adbd8749d0ffb505631912f6fe7e12d34'
            'a833d13aad3b30d5718cc952dcdbf26dfb023ebb3282d20f14bb9889f195561f'
            '9c7aa9721fe0b2c3cf3831a4d0b1720f13b070734d7be2702f820267ca11e277')

prepare() {
	cd "$srcdir/dokka-$pkgver"
	for patch in \
		'0001-enable-application-plugin.patch' \
		'0002-embed-plugin-dependencies.patch' \
		'0003-disable-gradle-enterprise.patch'
	do
		patch -N -p0 -i "../$patch"
	done
}

build() {
	cd "$srcdir/dokka-$pkgver"
	JAVA_HOME=/usr/lib/jvm/java-11-openjdk gradle :dokka-runners:runner-cli:distTar
	JAVA_HOME=/usr/lib/jvm/java-11-openjdk gradle :plugins:base:jar
}

package() {
	cd "$srcdir/dokka-$pkgver"
	mkdir -p "$pkgdir/usr/lib/dokka"
	tar xf "dokka-runners/runner-cli/build/distributions/cli-$pkgver.tar" --strip-components=1 -C "$pkgdir/usr/lib/dokka/"
	rm "$pkgdir/usr/lib/dokka/bin/cli.bat"
	install -Dm644 "plugins/base/build/libs/base-$pkgver.jar" "$pkgdir/usr/lib/dokka/plugins/base.jar"
	install -Dm755 ../dokka -t "$pkgdir/usr/bin/"
}